home *** CD-ROM | disk | FTP | other *** search
/ Run Magazine ReRun 1988 January & February / rerun-1988-01-02.d64 / menu 64 (.txt) < prev    next >
Encoding:
Commodore BASIC  |  1988-01-01  |  2.4 KB  |  77 lines
  1. 1 rem *********************************
  2. 2 rem *         'auto menu'           *
  3. 3 rem * reads directory & auto loads  *
  4. 4 rem * program selected by the user  *
  5. 5 rem *             by                *
  6. 6 rem * joe w. rocke          7/27/84 *
  7. 7 rem *********************************
  8. 10 poke53280,0:poke53281,0
  9. 20 dim n$(100):cx=54272:print "[147]"
  10. 30 print"[147][129]"
  11. 40 x$="                                       "
  12. 50 forx=1to5:printx$:next
  13. 60 print"":print chr$(117);
  14. 70 for x=1 to 38:printchr$(100);:next
  15. 80 printchr$(105);:for x=1 to 5
  16. 90 printchr$(103)spc(38)chr$(104)" "chr$(157);:next
  17. 100 printchr$(106);:for x=1 to 38:printchr$(102);:next:printchr$(107)
  18. 110 print""tab(14)"* auto menu *"
  19. 120 printtab(12)"[158]reading directory"
  20. 129 rem --- read disk directory ---
  21. 130 open1,8,0,"$"
  22. 140 get#1,b$:ifst<>0then260
  23. 149 rem --- line 150 limits to 26 files ---
  24. 150 iff>=27then260
  25. 160 ifb$<>chr$(34)then140
  26. 170 n$="":print"":poke 214,8:print
  27. 180 get#1,b$:ifb$<>chr$(34)thenn$=n$+b$:goto180
  28. 190 get#1,b$:ifb$=chr$(32)then190
  29. 199 rem -- following lines skip the loading files --
  30. 200 ifn$="menu 128"orn$="menu 64"orn$="runterm-hex"thenf=f-1:goto240
  31. 201 ifn$="boot.runterm128"orn$="runterm-punt-hex"thenf=f-1:goto240
  32. 202 ifn$="runterm xmod-hex"orn$="runterm tbls-hex"thenf=f-1:goto240
  33. 203 ifn$="runterm128"orn$="punter128"orn$="tables"thenf=f-1:goto240
  34. 204 ifn$="wxmodem128"thenf=f-1:goto240
  35. 205 ifn$="mouse 128 loader" orn$="spring"orn$="1987 index"thenf=f-1:goto240
  36. 206 ifn$="blank it 128"orn$="blank-it 128 ml"then f=f-1:goto240
  37. 210 ifn$="mouse editor"thenf=f-1:goto240
  38. 220 ifleft$(n$,1)=" "thenf=f-1:goto240
  39. 230 n$(f)=" "+n$
  40. 240 get#1,b$:ifb$<>""then240
  41. 250 ifst=0thenf=f+1:goto140
  42. 260 close1
  43. 269 rem - print first column of names -
  44. 270 fore=1tof/2:print"[153]"chr$(64+e)""n$(e):next
  45. 280 print"":poke214,8:print
  46. 289 rem -- then 2nd column of names ---
  47. 290 fore=f/2+1tof:printspc(20)"[153]"chr$(64+e)""n$(e):next
  48. 300 print""
  49. 310 printtab(12)"[158] press letter key "
  50. 320 printtab(5)"to auto load program selected"
  51. 330 getm$:ifm$=""then 330
  52. 335 ifm$=chr$(13)thenrun
  53. 340 ifm$=chr$(13)thenrun
  54. 350 ifm$<"a"orm$>chr$(64+f)then330
  55. 351 ifm$="f"then391
  56. 360 p=asc(m$)-64:print"[147]"
  57. 370 iflen(n$(p))>12thenn$(p)=left$(n$(p),12)+"*"
  58. 380 n$(p)=mid$(n$(p),2,len(n$(p)))
  59. 390 print"load"chr$(34)n$(p)chr$(34)",8[145][145][145]":goto460
  60. 391 p=asc(m$)-64:print"[147]"
  61. 392 iflen(n$(p))>15thenn$(p)=left$(n$(p),16)+"*"
  62. 393 n$(p)=mid$(n$(p),2,len(n$(p)))
  63. 394 print"load"chr$(34)n$(p)chr$(34)",8,1[145][145][145]"
  64. 400 rem *******************************
  65. 410 rem * if you know the pgm is 'ml' *
  66. 420 rem * the example below will load *
  67. 430 rem * and file & run it. examples *
  68. 440 rem * (3) are shown below.        *
  69. 450 rem *******************************
  70. 460 ifleft$(n$(p),5)="curso"then510
  71. 470 ifleft$(n$(p),7)="blank-i"thena$="sys890"+chr$(13):goto500
  72. 480 ifleft$(n$(p),5)="ultra"thena$="sys49152"+chr$(13):goto500
  73. 490 a$="run"+chr$(13)
  74. 500 poke631,13:forb=1tolen(a$):poke631+b,asc(mid$(a$,b,1)):next:poke198,10
  75. 505 new
  76. 510 a$="run 25"+chr$(13):goto500
  77.